Rewrite HTile and adapt components using it

Rewrite HTile in a more standard way, hopefully fixing the
mysterious segfault on some systems

src/gui/Base/HTile/ContentRow.qml

@@ -0,0 +1,12 @@
+// SPDX-License-Identifier: LGPL-3.0-or-later
+
+import QtQuick 2.12
+import ".."
+
+HRowLayout {
+    spacing: tile.spacing
+    opacity: tile.contentOpacity
+
+
+    property HTile tile
+}

src/gui/Base/HTile/HTile.qml

@@ -0,0 +1,65 @@
+// SPDX-License-Identifier: LGPL-3.0-or-later
+
+import QtQuick 2.12
+import ".."
+
+HButton {
+    id: tile
+
+
+    signal leftClicked()
+    signal rightClicked()
+    signal longPressed()
+
+
+    property bool compact: window.settings.compactMode
+    property real contentOpacity: 1
+
+    property alias contextMenu: contextMenuLoader.sourceComponent
+
+
+    Binding on topPadding {
+        value: spacing / 4
+        when: compact
+    }
+
+    Binding on bottomPadding {
+        value: spacing / 4
+        when: compact
+    }
+
+    TapHandler {
+        acceptedButtons: Qt.LeftButton
+        onTapped: leftClicked()
+        onLongPressed: tile.longPressed()
+    }
+
+    TapHandler {
+        acceptedButtons: Qt.RightButton
+        acceptedPointerTypes: PointerDevice.GenericPointer | PointerDevice.Pen
+        onTapped: {
+            rightClicked()
+            if (contextMenu) contextMenuLoader.active = true
+        }
+    }
+
+    TapHandler {
+        acceptedPointerTypes: PointerDevice.Finger | PointerDevice.Pen
+        onLongPressed: {
+            rightClicked()
+            if (contextMenu) contextMenuLoader.active = true
+        }
+    }
+
+    Connections {
+        enabled: contextMenuLoader.status === Loader.Ready
+        target: contextMenuLoader.item
+        onClosed: contextMenuLoader.active = false
+    }
+
+    HLoader {
+        id: contextMenuLoader
+        active: false
+        onLoaded: item.popup()
+    }
+}

src/gui/Base/HTile/HTileDelegate.qml

@@ -0,0 +1,21 @@
+// SPDX-License-Identifier: LGPL-3.0-or-later
+
+import QtQuick 2.12
+import QtQuick.Layouts 1.12
+import ".."
+
+HTile {
+    id: tile
+    onLeftClicked: {
+        view.highlightRangeMode    = ListView.NoHighlightRange
+        view.highlightMoveDuration = 0
+        activated()
+        view.highlightRangeMode    = ListView.ApplyRange
+        view.highlightMoveDuration = theme.animationDuration
+    }
+
+
+    signal activated()
+
+    property HListView view: ListView.view
+}

src/gui/Base/HTile/SubtitleLabel.qml

@@ -0,0 +1,24 @@
+// SPDX-License-Identifier: LGPL-3.0-or-later
+
+import QtQuick 2.12
+import QtQuick.Layouts 1.12
+import ".."
+
+HRichLabel {
+    textFormat: Text.StyledText
+    font.pixelSize: theme.fontSize.small
+    verticalAlignment: Qt.AlignVCenter
+    elide: Text.ElideRight
+    color: theme.colors.dimText
+    visible: Layout.maximumHeight > 0
+
+    Layout.maximumHeight: ! tile.compact && text ? implicitHeight : 0
+    Layout.fillWidth: true
+    Layout.fillHeight: true
+
+
+    property HTile tile
+
+
+    Behavior on Layout.maximumHeight { HNumberAnimation {} }
+}

src/gui/Base/HTile/TitleLabel.qml

@@ -0,0 +1,13 @@
+// SPDX-License-Identifier: LGPL-3.0-or-later
+
+import QtQuick 2.12
+import QtQuick.Layouts 1.12
+import ".."
+
+HLabel {
+    elide: Text.ElideRight
+    verticalAlignment: Qt.AlignVCenter
+
+    Layout.fillWidth: true
+    Layout.fillHeight: true
+}

src/gui/Base/HTile/TitleRightInfoLabel.qml

@@ -0,0 +1,23 @@
+// SPDX-License-Identifier: LGPL-3.0-or-later
+
+import QtQuick 2.12
+import QtQuick.Layouts 1.12
+import ".."
+
+HLabel {
+    font.pixelSize: theme.fontSize.small
+    verticalAlignment: Qt.AlignVCenter
+    color: theme.colors.halfDimText
+    visible: Layout.maximumWidth > 0
+
+    Layout.fillHeight: true
+    Layout.maximumWidth:
+        text && tile.width >= 200 * theme.uiScale ?
+        implicitWidth : 0
+
+
+    property HTile tile
+
+
+    Behavior on Layout.maximumWidth { HNumberAnimation {} }
+}